指标功能：[B]国产软件[/B]
指标类型：简体中文
所需积分：0
推荐星级：
授权方式：共享版
公式大小：0 Bytes
更新时间：2012-03-02 09:01:00
公式简介:

现在我把给庄家评分过程【还有评分的具体百分比】写出来好复杂但很好用，在分时里就能清楚的看清庄家意图，加上主动率。委托买卖的意向，把他们放在一起看在分时里炒股就更离不开他了，源码一并发表，对以前加密的部分，你也就清楚了。引用的我不再发了【05引】【BSVOL】在0598系列里你们都有。会编公式的也可以用评分选股，不明白真假主动率你看源码也就明白了，祝你好运，
variable:涨量=0;variable:平量=0;variable:跌量=0;variable:真主动率=0;variable:假主动率=0;
DRAWRECTREL(-1,0,1000,1000,RGB(0,0,50)),color0077FF,LINETHICK2,LAYER7;-3,COLOR000000;
50;
{分时排序}
真主动率:("BSVOL.真主动率#tick") ,color0000FF,linethick2,PRECIS1,LAYER0;
假主动率:("BSVOL.假主动率#tick"),color00FF00,linethick2,PRECIS1,LAYER0;
DRAWTEXTABS(0,20,'【真主动率】▄ '+NUMTOSTRN(真主动率,1)+'%,'),linethick2,color0000FF;
DRAWTEXTABS(0,35,'【假主动率】▄ '+NUMTOSTRN(假主动率,1)+'%,'),linethick2,color00ff00;
真主动净量:"BSVOL.真主动净量#tick",color00FF00,linethick0,LAYER0;
fillrgn(真主动率,假主动率,真主动净量>0,RGB(0,0,255),真主动净量<0,RGB(0,80,80));

JA5:REF(C,BARSLAST(TIME>093459 AND TIME<093501)),LINETHICK0;
JA10:REF(C,BARSLAST(TIME>093959 AND TIME<094001)),LINETHICK0;
JA15:REF(C,BARSLAST(TIME>094459 AND TIME<094501)),LINETHICK0;
JA30:REF(C,BARSLAST(TIME>092959 AND TIME<100001)),PRECIS2,LINETHICK0;
JV30:REF(SUM(V,30)/SUM("05引.RMV#DAY"/240,30)*100,BARSLAST(TIME>092959 AND TIME<100001)),LINETHICK0;
{主动买卖差30}
主动买B:"BSVOL.主动买#tick",Color0000ff,PRECIS0,linethick0;
主动卖B:"BSVOL.主动卖#tick",Color00ff00,PRECIS0,linethick0;
主动买30:REF(主动买B,BARSLAST(TIME>092959 AND TIME<100001)),LINETHICK0;
主动卖30:REF(主动卖B,BARSLAST(TIME>092959 AND TIME<100001)),LINETHICK0;

{涨跌量差30}
涨量:=IF(C>ref(c,1),VOL,0);
跌量:=IF(C<ref(c,1),VOL,0);
涨量占30:=SUM(涨量,30)/SUM(V,30)*100;
跌量占30:=SUM(跌量,30)/SUM(V,30)*100;
涨跌量30:REF(涨量占30-跌量占30,BARSLAST(TIME>092959 AND TIME<100001)),LINETHICK0;

{均线上-均线下}
tt:=BARSCOUNT(C);
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均线:=IF(zz1=0,MA(C,TT),zz);
KK:=if(CLOSE>=均线,1,0);
均线上:=COUNT(KK=1 ,0 );
均线下:=COUNT(KK=0 ,0 );
均线上占:=(均线上)/(均线上+均线下)*100;
均线下占:=(均线下)/(均线上+均线下)*100;
线上下:REF((均线上占-均线下占),BARSLAST(TIME>092959 AND TIME<100001)),LINETHICK0;

主动买:DYNAINFO(23),Color0000ff,PRECIS0,linethick0;
主动卖:DYNAINFO(22),Color00ff00,PRECIS0,linethick0;

YD:="05引.RC#DAY";
Mm:=if(c=DYNAINFO(54) and l=DYNAINFO(54),H-yd,h-ref(c,1));
m:=if(mm>0,mm,0.0);
Ss:=if(c=DYNAINFO(55) and h=DYNAINFO(55),yd-L,ref(c,1)-L);
s:=if(ss>0,ss,0.0);
Hj:=m+s;
买入K:=m/hj*AMOUNT/CAPITAL;
卖出K:=s/hj*AMOUNT/CAPITAL;
买入力度:sum(买入K,0),LINETHICK0,color00FFFF;
卖出力度:sum(卖出K,0),LINETHICK0,colorFFFF00;

委托买:="BSVOL.委托买#tick";
委托卖:=-"BSVOL.委托卖#tick";
MMB:EMA(委托卖/(委托买+委托卖)*100,10),color00ffFF,linethick2,LAYER4;
DRAWTEXT( BARSTATUS=2,MMB ,'【委卖'+ NUMTOSTRN(委托卖/(委托买+委托卖)*100,0)+'%】' ),ALIGN2,COLOR0000FF,linethick3,layer0;

昨天同期量:=SUM("05引.RV#DAY"/240,0);
今天当前量:=SUM(VOL,0);
昨天MA5量:=SUM("05引.RMV#DAY"/240,0);
今天VOL量:=SUM(VOL,0);

涨量占:SUM(涨量,0)/SUM(V,0)*100,color0000FF,linethick0,layer0;
跌量占:SUM(跌量,0)/SUM(V,0)*100,color00FF00,linethick0,layer2;
涨跌量差:(涨量占-跌量占),PRECIS1,linethick0;
平量:=IF(C=ref(c,1),VOL,0);
平量占:SUM(平量,0)/SUM(V,0)*100,COLOR00FFff,linethick0,LAYER3;

开盘评分:IF((JA5-DYNAINFO(4))>0,1,0) +IF((JA10-JA5)>0,1,0)+ IF((JA15-JA10)>0,1,0)+IF((JA30-JA15)>0,1,0)+ IF(JV30>100,1,0) + IF((主动买30>主动卖30),1,0) + IF((涨跌量30>0),1,0) + IF((线上下>50),1,0),PRECIS0,LINETHICK0;
DRAWTEXTREL(0,5,'【开盘评分:▄ '+NUMTOSTRN(开盘评分,0)+'分】'),color00FFff,LINETHICK3,LAYER0;;
盘中评分:(IF((涨量占>跌量占),1,0) +IF((均线上>均线下),1,0)+ IF((主动买>主动卖),1,0)+IF((买入力度>卖出力度),1,0)+ IF((委托买<委托卖),1,0) + IF((今天当前量>昨天同期量),1,0) + IF((今天VOL量>昨天MA5量),1,0) + IF(ABS(真主动率)>ABS(假主动率),1,0))*10,PRECIS0,colorff9900,LINETHICK2,layer3;
盘中:(涨量占/(涨量占+跌量占)*100+均线上/(均线上+均线下)*100+主动买/(主动买+主动卖)*100+买入力度/(买入力度+卖出力度)*100+委托卖/(委托卖+委托买)*100+今天当前量/(今天当前量+昨天同期量)*100+今天VOL量/(今天VOL量+昨天MA5量)*100+ABS(真主动率)/(ABS(真主动率)+ABS(假主动率))*100)/8,colorff99ff,LINETHICK0;
DRAWTEXT( BARSTATUS=2,盘中评分+7 ,'【'+ NUMTOSTRN(盘中,1)+'%】' ),ALIGN0,COLORff99ff,linethick3,layer0;
DRAWTEXT( BARSTATUS=2,盘中评分 ,'【盘中'+ NUMTOSTRN(盘中评分/10,0)+'分】' ),COLOR00ff00,linethick3,layer0;
 

 

[url=http://www.goodgupiao.com/gupiaogongshi/18115.html][B]看清给庄家评分过程炒股好的很(副图、源码、贴图)[/B][/url]