指标功能：[B]国产软件[/B]
指标类型：简体中文
所需积分：0
推荐星级：
授权方式：共享版
公式大小：0 Bytes
更新时间：2012-03-05 08:59:00
公式简介:

实时解盘，如果高手能帮改成通达信版非常感谢。

M :=9;
P1:=5;
P2:=10;
P3:=20;
P4:=30;
LONG:=26;
SHORT:=12;
MA1:= EMA(C,P1);
MA2:= EMA(C,P2);
MA3:= EMA(C,P3);
MA4:= EMA(C,P4);
MA5:= MA(C,120);
换手率:=(VOL/CAPITAL) ;
{========================= 引用布林线 =========================}
N:=26; P:=20;
MID := MA(CLOSE,N);
UPPER:=MID + P/10*STD(CLOSE,N);
LOWER:=MID - P/10*STD(CLOSE,N);
多头排列:=MA1>MA2 and MA2>MA3 and MA2>MA4 and MA4>ref(MA4,5);
空头排列:=MA1<MA2 and MA2<MA3 and MA3<MA4;
上升趋势:=MA4>ref(MA4,3) and MA4>ref(MA4,1) and MA1>MA4;
下跌趋势:=MA4<ref(MA4,3) and MA4<ref(MA4,1) and MA1<MA4;
{
EXPLAIN(C>0,'=====【综合解盘】====='),COLORRED; EXPLAIN(C>0,'注意：目前解盘内容仅适用'); EXPLAIN(C>0,'于个股的日线周期分析参考');
}
{=================================================【基本信息提示】====================================================}
EXPLAIN(C>0,'───【基本信息提示】───'),COLORYELLOW;
EXPLAINEX(1,'流 通 盘(万股)：',FINANCE(3), 1,0);
EXPLAINEX(1,'总 股 本(万股)：',FINANCE(0), 2,0);
EXPLAINEX(1,'每股收益( 元 )：',FINANCE(29),3,0);
{
EXPLAINEX(1,'动态市盈率：',close/FINANCE(29),2,0);
}
EXPLAINEX(close>FINANCE(34),'每股净资产(元)：',FINANCE(31),3,0) ;
EXPLAINEX(close<FINANCE(34),'每股净资产(元)：',FINANCE(31),3,0) ;
EXPLAINEX(1,'净资产收益率 %：',FINANCE(33),2,0);
{EXPLAIN(C>0,'────────────'),COLOR666666;}
EXPLAINEX(1=1,'获利盘比例值 %：',WINNER(c)*100,2,0);
{
EXPLAINEX(1,'总 股 本:',FINANCE(1),'流 通 股:',FINANCE(7),2,0);
EXPLAINEX(1,'主营利润：',FINANCE(21),2,0);
EXPLAINEX(1,'利润增长：',FINANCE(54),2,0);
EXPLAIN(1,F10TEXT(F10FIND('发行价',1),30));
EXPLAINEX(1,'获利盘 %：',winner(close)*100,2,0),COLORGREEN;
}
{
EXPLAIN(C>0,'──【板块信息提示】──'),COLORBLUE;
Explain(1,BLKNAME);
Explain(1,STKNAME+STKLABEL+'\n所属板块:'+BLKNAME)
}
{=================================================【MACD指标分析】====================================================}
EXPLAIN(C>0,'───【经典指标分析】───'),COLORYELLOW;
DIF :EMA(CLOSE,SHORT)-EMA(CLOSE,LONG),COLORCCFFFF;
DEA :EMA(DIF,M),COLOR58FF58;
MACD:=2*(DIF-DEA),COLORFFFF00,LINETHICK0;
STICKLINE(MACD>=0 AND MACD>=REF(MACD,1),0,MACD,6,0),COLOR6058FF;
STICKLINE(MACD>=0 AND MACD< REF(MACD,1),0,MACD,6,1),COLOR6058FF;
STICKLINE(MACD<0 AND MACD>=REF(MACD,1),0,MACD,6,1),COLORFFFF00;
STICKLINE(MACD<0 AND MACD< REF(MACD,1),0,MACD,6,0),COLORFFFF00;
多头趋势:=IF(DIF>=0 AND DEA>=0 OR (DIF<0 AND DEA>=0),1,0);
空头趋势:=DIF<0 AND DEA<0 OR (DIF>=0 AND DEA<0);
MACD绿柱缩短:=MACD<0 AND ABS(MACD)< REF(ABS(MACD),1) and ref(MACD,1)<0;
MACD红柱缩短:=MACD>0 AND MACD< REF(MACD,1);
缩头:=IF(MACD>0 AND REF(MACD,1)>REF(MACD,2) AND REF(MACD,2)>REF(MACD,3) AND MACD< REF(MACD,1),1,0) and ref(MACD,1)>0.150;
缩脚:=IF(MACD<0 AND REF(MACD,1)< REF(MACD,2) AND REF(MACD,2)< REF(MACD,3) AND MACD>REF(MACD,1),1,0) and ref(MACD,1)<-0.100;
金叉:=CROSS(DIF,DEA);
死叉:=CROSS(DEA,DIF);
0轴下死叉:=死叉 AND DEA<0;
0轴上死叉:=死叉 AND DEA>0;
0轴下金叉:=金叉 AND DEA<0;
0轴上金叉:=金叉 AND DEA>0;
0轴上二次金叉:=COUNT(CROSS(DIF,DEA) AND DEA>0,20)=2 AND CROSS(DIF,DEA) AND DEA>0;
0轴上三次金叉:=COUNT(CROSS(DIF,DEA) AND DEA>0,20)=3 AND CROSS(DIF,DEA) AND DEA>0;
{----------------------------------------------------------------------------------------------------------------------------}
{
EXPLAIN(缩头, '注意MACD柱状缩头') ;
EXPLAIN(缩脚, '注意MACD柱状缩脚') ;
EXPLAIN(MACD<0 AND ABS(MACD)>REF(ABS(MACD),1), 'MACD绿柱增长');
EXPLAIN(MACD绿柱缩短 and not(缩脚),'MACD绿柱缩短');
EXPLAIN(MACD>0 AND MACD>REF(MACD,1), 'MACD红柱增长');
EXPLAIN(MACD红柱缩短 and not(缩头),'MACD红柱缩短');
}
EXPLAIN(金叉 and not(0轴下金叉) and not(0轴上金叉) and not( 0轴上二次金叉),'金叉--属强势信号');
EXPLAIN( 0轴下死叉,'DEA和DIF在0轴下死叉');
EXPLAIN( 0轴下金叉,'DEA和DIF在0轴下金叉');
EXPLAIN( 0轴上金叉 and not(0轴上二次金叉) and not(0轴上三次金叉),'DEA和DIF在0轴上金叉');
EXPLAIN( 0轴上死叉,'DEA和DIF在0轴上死叉');
EXPLAIN( 0轴上二次金叉,'DEA和DIF在0轴上二次金叉');
EXPLAIN( 0轴上三次金叉,'DEA和DIF在0轴上三次金叉');
EXPLAIN(DIF>=0 AND MACD>=0 AND MACD<=REF(MACD,1),'上涨趋势有所减缓，短线投资者可考虑先逢高减持');
EXPLAIN(DIF<0 AND MACD>0 AND MACD>REF(MACD,1) , '目前处于反弹阶段，保持谨慎');
EXPLAIN(MACD>0 AND DIF>0 AND DIF>DEA AND DIF>REF(DIF,1) AND C>REF(C,1),'上升趋势尚未改变');
EXPLAIN(DIF<0 AND MACD>0 AND MACD< REF(MACD,1),'短线反弹已经结束，应继续坚持谨慎原则');
EXPLAIN(DIF<0 AND MACD<=0 AND MACD>REF(MACD,1),'下跌趋势有所减缓，可适当关注');
EXPLAIN(MACD<0 AND DIF<0 AND DIF< DEA AND DIF< REF(DIF,1) AND C< REF(C,1) AND MACD<=REF(MACD,1),'下降趋势尚未改变');
EXPLAIN(DIF>=0 AND MACD<0 AND MACD< REF(MACD,1),'目前正处于回落整理阶段');
EXPLAIN(DIF>=0 AND MACD<0 AND MACD>=REF(MACD,1),'目前仍处于整理阶段，但整理即将结束，可在均线或其他支撑位附近逢低介入');
{--------------------------------------------引用 趋势顶底指标分析---------------------------------------------------}
A:=MA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),19),COLORRED;
B:=-100*(HHV(HIGH,14)-CLOSE)/(HHV(HIGH,14)-LLV(LOW,14));
d:=EMA(-100*(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LLV(LOW,34)),4),linethick2;
长期线:=A+100; 短期线:=B+100; 中期线:=d+100;
见顶:=(ref(中期线,1)>85 and ref(短期线,1)>85 and ref(长期线,1)>65) and cross(长期线,短期线) ;
顶部区域:=(中期线<ref(中期线,1) and ref(中期线,1)>80) and (ref(短期线,1)>95 or ref(短期线,2)>95 ) and 长期线>60 and 短期线<83.5 and 短期线<中期线 and 短期线<长期线+4;
底部区域:=(长期线<12 and 中期线<8 and (短期线<7.2 or ref(短期线,1)<5) and (中期线>ref(中期线,1) or 短期线>ref(短期线,1)))
or (长期线<8 and 中期线<7 and 短期线<15 and 短期线>ref(短期线,1)) or (长期线<10 and 中期线<7 and 短期线<1) ;
EXPLAIN( 顶部区域,'走势有超买迹象，需要引起注意') ,COLORFFCC99;
EXPLAIN( 底部区域,'走势有超跌迹象，需要引起注意') ,color9966FF;
{=================================================【均线信息提示】====================================================}
EXPLAIN(C>0,'───【均线趋势分析】───'),COLORYELLOW;
一阴穿两线:=close/open<0.985 and high>MA1 and close<MA3;
一阳穿两线:=close/open>1.016 and low<min(MA1,MA3) and close>max(MA1,MA3);
均线密集:=上升趋势 and (max(MA1,MA4)/min(MA1,MA4))<1.01 and MA1>MA2;
均线发散程度:=MA1/MA4;
均线向下发散:=空头排列 and 均线发散程度<0.90 and 均线发散程度<0.99*ref(均线发散程度,1);
均线向上发散:=多头排列 and 均线发散程度>1.070 and 均线发散程度>(1.013*ref(均线发散程度,1));
上升趋势形成:=上升趋势 and MA1>ref(MA1,1) and ref(not(上升趋势),1);
EXPLAIN(上升趋势 and MA1>ref(MA1,1) and ref(not(上升趋势),1) ,'上升趋势形成'),colorred;
EXPLAIN(上升趋势 and not(一阴穿两线) and ref(上升趋势,1) ,'处于上升趋势'),color9966FF;
EXPLAIN((not(上升趋势) or 一阴穿两线) and ref(上升趋势,1) ,'上升趋势停顿，注意行情可能转折'),color88CC66;
EXPLAIN(下跌趋势 and MA1<ref(MA1,1) and ref(not(下跌趋势),1) ,'下跌趋势形成');
EXPLAIN(下跌趋势 and not(一阳穿两线) and ref(下跌趋势,1) ,'处于下跌趋势');
EXPLAIN((not(下跌趋势) or 一阳穿两线) and ref(下跌趋势,1) and not(上升趋势形成) ,'下跌趋势趋缓，注意行情可能转折'),color00CCFF;
EXPLAIN(多头排列 and not(均线向上发散) ,'均线多头排列');
EXPLAIN(多头排列 and 均线向上发散 ,'均线多头向上发散，注意K线形态和股价运行节奏变化'),color3333CC;
EXPLAIN(空头排列 and not(均线向下发散) ,'均线空头排列');
EXPLAIN(空头排列 and 均线向下发散 ,'均线空头向下发散，注意K线形态和股价运行节奏变化'),color3333CC;
EXPLAIN(均线密集 ,'均线密集排列,注意走势方向变化'),color6633CC;
{=================================================K线特征及形态组合====================================================}
涨停板 :=CLOSE/REF(CLOSE,1)>1.097;
跌停板 :={close<=open and} CLOSE/REF(CLOSE,1)<0.91;
K线实体 :=abs(close-open);
阳线 :=CLOSE>OPEN or 涨停板;
带下影阳线:=(阳线 or 涨停板) and (close-low)>1.6*(close-open);
光脚阳线:=阳线 and (open-low)<0.36*(close-open);
中阳线 :=close/open>1.030;
短上影阳线:=阳线 and (high-close)<(high-open)*0.34;
阴线 :=CLOSE<OPEN;
中阴线 :=close/ref(close,1)<0.970;
平盘 :=CLOSE=OPEN;
平台整理:=HHV(close,5)/LLV(open,5)<1.08;
{=====================================================================================================================}
长十字 :=CLOSE=OPEN AND high>open and HIGH/LOW >1.06;
垂死十字 :=CLOSE=OPEN AND CLOSE=LOW AND CLOSE<>HIGH;
倒转锤头 :=HIGH-LOW > 2.5*(MAX(OPEN,CLOSE)-LOW) AND CLOSE<min(MA1,MA2) and (min(open,close)-low)/(high-low)<0.10 and open<MA1 and MA1<MA2 and open<>close;
锤头 :=HIGH = MAX(OPEN,CLOSE) AND HIGH-LOW>3*(HIGH-MIN(OPEN,CLOSE)) AND CLOSE<MA(CLOSE,10);
吊颈 :=(OPEN<>CLOSE and ((HIGH-MAX(OPEN,CLOSE))/(high-low))<0.16 ) AND (HIGH-LOW)>2.48*(abs(OPEN-CLOSE)) AND CLOSE>MA1 and (high-low)/low>0.020;
十字星 :=(abs(CLOSE-OPEN))/(high-Low)<0.19 and (abs(CLOSE-OPEN)/CLOSE)<0.009 AND HIGH>LOW and max(open,close)<high and min(open,close)>low
and not(长十字) and not(倒转锤头) and not(吊颈);
早晨之星 :=REF(CLOSE,2)/REF(OPEN,2)<0.97 AND REF(OPEN,1)<=REF(CLOSE,2) AND (REF(十字星,1) or ref(长十字,1)) AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
黄昏之星 :=REF(CLOSE,2)/REF(OPEN,2)>1.03 AND REF(OPEN,1)>=REF(CLOSE,2) AND (REF(十字星,1) or ref(长十字,1)) AND CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2);
射击之星 :=MIN(OPEN,CLOSE)=LOW AND HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND CLOSE > MA(CLOSE,5) and MA1>MA2;
升势尽头 :=ref(阳线,1) and ref(high,1)/ref(close,1)>1.008 and (abs(close-open)/open<0.018 or 吊颈) and (max(close,open)<ref(high,1) or (close<open
and max(close,open)<=ref(high,1))) and min(close,open)>ref(close,1) and MA1>MA2;
跌势尽头 :=ref(阴线,1) and ref(阴线,2) and ref(close,1)/ref(open,1)<0.98 and ref(low, 1)/ref(close,1)<0.988 and (abs(close-open)/open<0.025 or 倒转锤头) and max(close,open)<ref(close,1)
and min(close,open)>ref(low,1) and 空头排列;
穿头破脚1 :=ABS((REF(CLOSE,1)-REF(OPEN,1))/REF(OPEN,1)<0.02 AND CLOSE/OPEN<0.986 AND CLOSE<min(REF(OPEN,1),REF(CLOSE,1)) AND OPEN>max(REF(CLOSE,1),REF(open,1))) and ref(Open,1)>max(MA1,MA2);
穿头破脚2 :=(REF(CLOSE,1)/REF(OPEN,1)<0.990 AND CLOSE/OPEN>1.03 AND CLOSE>REF(OPEN,1) AND OPEN<REF(CLOSE,1));
乌云盖顶 :=REF(CLOSE,1)/REF(OPEN,1)>1.02 AND CLOSE/OPEN<0.97 AND OPEN>REF(CLOSE,1) AND CLOSE<((REF(CLOSE,1) + REF(OPEN,1))/2) and close>ref(open,1);
曙光初现 :=REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.04 AND OPEN<REF(CLOSE,1) AND close>( REF(open,1)+REF(close,1))/2 and ref(close,1)<MIN(ref(MA1,1),ref(MA2,1));
旭日东升 :=REF(CLOSE,1)/REF(OPEN,1)<0.985 AND 阳线 and close/open>1.020 AND OPEN>REF(CLOSE,1) AND OPEN<REF(open,1) AND CLOSE>REF(OPEN,1) AND LOW<MA1 and ref(空头排列,1);
身怀六甲1 :=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1)>0.017 AND ABS(CLOSE-OPEN)/CLOSE<0.05 AND MAX(CLOSE,OPEN)<MAX(REF(CLOSE,1),REF(OPEN,1)) AND MIN(CLOSE,OPEN) > MIN(REF(CLOSE,1),REF(OPEN,1))
and ref(阳线,1) and ref(close,1)>MA1;
身怀六甲2 :=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1)>0.017 AND ABS(CLOSE-OPEN)/CLOSE<0.04 AND MAX(CLOSE,OPEN)<MAX(REF(CLOSE,1),REF(OPEN,1)) AND MIN(CLOSE,OPEN) > MIN(REF(CLOSE,1),REF(OPEN,1))
and ref(阴线,1) and ref(close,1)<MA2;
十字胎 :=ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1)>0.04 AND CLOSE=OPEN AND CLOSE < MAX(REF(CLOSE,1),REF(OPEN,1)) AND CLOSE > MIN(REF(CLOSE,1),REF(OPEN,1));
平顶 :=ABS(HIGH-REF(HIGH,1))/HIGH<0.0005 and max(open,close)>max(MA2,MA4) and max(high,ref(high,1))>=hhv(high,8) and 阴线;
平底 :=(ABS(LOW-REF(LOW,1))/LOW<0.001 and abs(ref(low,1)-ref(low,2))/ref(low,1)<=0.001) and 阳线 and min(open,close)<MA1;
大阴烛 :=OPEN/CLOSE>1.06 AND HIGH/LOW <(OPEN/CLOSE+0.030);
大阳烛 :=CLOSE/OPEN>1.07 AND 100*(HIGH/LOW) < 100*(CLOSE/OPEN)+2.3;
光脚阴线 :=LOW=CLOSE and close/open<0.97;
光脚长阴 :=光脚阴线 and 大阴烛;
光头阳线 :=HIGH=CLOSE AND HIGH<>LOW and 中阳线;
低开大阳 :=CLOSE/OPEN>1.06 AND open=low and Open<ref(low,1) and open<MA1;
双飞乌鸦 :=REF(阴线,1) AND 阴线 AND ref(阳线,2) AND CLOSE/OPEN<0.988 and close<ref(close,1) and ref(not(阴线),2) and ref(多头排列,2) and open<=ref(close,1);
多方炮 :=REF(阳线,2) and ref(close,2)/ref(open,2)>1.014 AND REF(阴线,1) AND 阳线 and close>(ref(close,1)+ref(open,1))/2 and close/open>1.023 and open<ref(open,1);
空方炮 :=REF(阴线,2) and ref(open,2)/ref(close,2)>1.02 AND REF(阳线,1) AND 阴线 and close<(ref(close,1)+ref(open,1))/2 and open/close>1.03 and low<ref(open,1) ;
出水芙蓉 :=(OPEN<EMA(C,10) OR OPEN<EMA(C,20)) AND (C>MAX(EMA(C,10),MAX(EMA(C,20),EMA(C,30)))) AND (V/MA(V,30)>1.2 AND C/REF(C,1)>1.049);
上升三部曲 :=REF(CLOSE,4)/REF(OPEN,4)>1.016 AND REF(阴线,3) AND REF(阴线,2) AND REF(close<=open,1) AND REF(LOW,4)<REF(LOW,3) AND REF(LOW,4)<REF(LOW,2) AND REF(LOW,4)<REF(LOW,1)
AND CLOSE/OPEN>1.015 AND CLOSE>REF(CLOSE,4) AND REF(HIGH,4)>REF(close,3) AND REF(HIGH,4)>REF(close,2) AND REF(HIGH,4)>REF(close,1) and (HIGH-CLOSE)/(HIGH-OPEN)<0.30;
上升二法 :=REF(CLOSE,3)/REF(OPEN,3)>1.02 AND REF(阴线,2) AND REF(close<=open,1) AND ref(open,1)<ref(close,2) AND REF(LOW,3)<REF(LOW,2) AND REF(LOW,3)<REF(LOW,1)
AND CLOSE/OPEN>1.013 AND CLOSE>REF(CLOSE,3) ;
下跌三部曲 := REF(中阴线,4) AND REF(阳线,3) AND REF(阳线,2) AND REF(阳线,1) AND REF(close,4)<REF(open,3) AND REF(close,4)<REF(open,2) AND REF(close,4)<REF(open,1)
AND REF(HIGH,4)>REF(HIGH,3) AND REF(HIGH,4)>REF(HIGH,2) AND REF(HIGH,4)>REF(close,1) AND 中阴线 AND CLOSE<REF(CLOSE,4);
跳空缺口1 :=LOW>REF(HIGH,1) and ref(not(多头排列),1);
跳空缺口2 :=HIGH<REF(LOW,1);
见顶缺口 :=LOW>REF(HIGH,1) and open>MA1 and (high-max(close,open))/close>0.02 and 多头排列 and 均线向上发散 and not(均线密集) and ref(close,1)>UPPER;
三只乌鸦 :=REF(阴线,2) AND REF(阴线,1) AND 阴线 AND REF(CLOSE,1)<REF(CLOSE,2) AND CLOSE<REF(CLOSE,1)
and ref(close>open ,3) and REF(open,2)>max(ref(MA1,2),ref(MA2,2)) and ref(多头排列,3) and close<MA2;
加速三阴 :=(REF(阴线,2) or (ref(平盘,2) and ref(open,2)<ref(MA1,2))) AND REF(阴线,1) AND 阴线 AND REF(CLOSE,1)<REF(CLOSE,2)*0.95 AND CLOSE<REF(CLOSE,1)
and REF(close,2)<min(ref(MA1,2),ref(MA3,2)) and ref(空头排列,1) and close/open<0.975 and (close-low)/(open-low)<0.35
and ((open<=(ref(close,1)*1.005) and close/open<0.95) or (open<ref(close,1)));
冲顶三阳 :=(REF(阳线,2) AND REF(阳线,1) AND 阳线) and (K线实体/open)>0.04 and K线实体>ref(K线实体,1)*0.9 and ref(K线实体,1)>ref(K线实体,2) and
多头排列 and ref(CLOSE,1)/ref(close,2)>1.030 and open>=ref(close,1) and (not(涨停板) or (涨停板 and 换手率>20) );
看涨分离 :=OPEN=REF(OPEN,1) AND (CLOSE-OPEN)*(REF(CLOSE,1)-REF(OPEN,1))<0 and ref(阴线,1) and not(十字星);
看跌分离 :=OPEN=REF(OPEN,1) AND (CLOSE-OPEN)*(REF(CLOSE,1)-REF(OPEN,1))<0 and ref(阳线,1);
长下影 :=(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667 and (min(close,open)-Low)/Low>0.02 and not(涨停板);
长上影 :=(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.38 and (high-max(close,open))/close>0.025 and max(open,close)>MA1 and not(倒转锤头) ;
好友反攻 :=(REF(阴线,1) AND 阳线 AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002 ) and 中阳线;
坏友反攻 :=(REF(阳线,1) AND 阴线 AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002) and 中阴线;
看涨吞没 :=ref(阴线,1) and 中阳线 and open<=min(ref(open,1),ref(close,1)) and close>max(ref(open,1),ref(close,1)) and not(穿头破脚2) and (HIGH-CLOSE)/(HIGH-OPEN)<0.30;
看跌吞没 :=ref(阳线,1) and 中阴线 and open>=max(ref(open,1),ref(close,1)) and close<min(ref(open,1),ref(close,1)) and not(穿头破脚1);
倾盆大雨 :=REF(C,1)/REF(O,1)>=1.02 AND O<REF(C,1) AND O>REF(O,1) AND C<REF(O,1) and close/open<0.965 and ref(多头排列,1);
断头铡刀 :=close/open<0.98 and ref(MA1,1)>ref(MA4,1) and close<min(MA2,MA4) and open>=max(MA1,MA2) and (close-low)/low<0.015
and close<min(ref(open,1),ref(close,1));
{=============================================================================================================================}

EXPLAIN(C>0,'───【K 线形态分析】───'),COLORYELLOW;

EXPLAIN( 倾盆大雨 ,'[倾盆大雨] 在高位出现往往是见顶信号；');
EXPLAIN( 断头铡刀 ,'[断头铡刀] 破位下跌,行情发展将可能发生逆转,务必注意防范风险；');
EXPLAIN( 好友反攻 ,'[好友反攻] 跌势已尽,可能展开一段反弹行情；');
EXPLAIN( 坏友反攻 ,'[坏友反攻] 升势将尽,可能展开一段下跌行情；');
EXPLAIN( 跳空缺口1 ,'[跳空缺口] 若突破长期盘整走势,向上跳空意味着上涨行情开始；若出现在上涨途中为中继形态；');
EXPLAIN( 跳空缺口2 ,'[跳空缺口] 低开向下跳空,空头力量占优不过需注意区别缺口位置；');
EXPLAIN( 见顶缺口 ,'[冲顶缺口] 若在长期升势之后向上跳空,放量收出带长上影K线，注意上涨行情有结束可能；');
EXPLAIN( 升势尽头 ,'[升势尽头] 长期升势之后收出小实体K线，注意行情有可能临近结束；');
EXPLAIN( 跌势尽头 ,'[跌势尽头] 长期跌势之后向下跳空,收出小实体K线，注意下跌行情有可能停顿；');
EXPLAIN( 三只乌鸦 ,'[三只乌鸦] 可能见顶回落；');
EXPLAIN( 加速三阴 ,'[加速三阴] 若在下跌末期出现有加速赶底的意味；');
EXPLAIN( 冲顶三阳 ,'[冲顶三阳] 若在上涨末期出现有加速赶顶的意味；');

EXPLAIN( 看涨分离 ,'[看涨分离] 有看涨可能；');
EXPLAIN( 看跌分离 ,'[看跌分离] 有看跌可能；');
EXPLAIN( 下跌三部曲 ,'[下跌三法] 典型看跌信号，但是力度不强；');
EXPLAIN( 上升三部曲 ,'[上升三法] 典型看涨信号，但是力度不强；');
EXPLAIN( 上升二法 ,'[上升二法] 看涨信号；');
EXPLAIN( 十字星 ,'[十 字 星] 警示性信号,原趋势可能停顿或变化；');
EXPLAIN( 长十字 ,'[长 十 字] 重要警告信号,原趋势可能停顿或反转；');
EXPLAIN( 垂死十字 ,'[垂死十字] 下跌信号；');
EXPLAIN( 早晨之星 ,'[早晨之星] 上涨信号,见底回升；');
EXPLAIN( 黄昏之星 ,'[黄昏之星] 趋势停顿或反转,下跌信号,见顶回落；');
EXPLAIN( 射击之星 ,'[流 星 线] 出现在短期的上升趋势,表明市场顶部就在眼前,可能见顶回落,可靠性低；');
EXPLAIN( 倒转锤头 ,'[倒转锤头] 构成一个警示信号,有可能将见底企稳；');
EXPLAIN( 锤头 ,'[ 锤 头 ] 可能见底回升,如有成交量配合,反弹意味较强；');
EXPLAIN( 吊颈 ,'[吊 颈 线] 上升行情中常于阶段顶部附近出现,若是以涨停报收有可能是上升中继形态；');
EXPLAIN( 平顶 ,'[ 平 顶 ] 意味行情摸高见顶,股价运行有可能将要转折。；');
EXPLAIN( 乌云盖顶 ,'[乌云盖顶] 见顶回落信号;在上升途中有试盘和洗盘的可能；');
EXPLAIN( 曙光初现 ,'[曙光初现] 行情可能演化为V型反转或止跌盘整，后市有望探底回升');
EXPLAIN( 旭日东升 ,'[旭日东升] 行情可能演化为V型反转或止跌横盘趋势。比较强烈的反弹信号，后市见底回升；');
EXPLAIN( 身怀六甲1 ,'[身怀六甲] 上升趋势停顿信号，若出现在高位，有见顶回落可能；也常出现于整理形态');
EXPLAIN( 身怀六甲2 ,'[身怀六甲] 若出现在底部，是下跌趋势停顿信号，有见底回升可能；');
EXPLAIN( 平底 ,'[ 平 底 ] 行情探低见底,股价行将反转上升,但力度较小；');
EXPLAIN( 双飞乌鸦 ,'[双飞乌鸦] 走势疲软可能见顶回落');
EXPLAIN( 多方炮 ,'[多 方 炮] 在底部出现有上涨可能,在上涨途中出现是上涨中继,高位出现可能是复合见顶信号；');
EXPLAIN( 空方炮 ,'[空 方 炮] 在顶部出现有下跌可能,在下跌途中出现是下跌中继,低位出现往往是加速赶底信号；');
EXPLAIN( 看涨吞没 ,'[看涨吞没] 在底部出现有上涨可能,在中间出现有可能是上涨中继；');
EXPLAIN( 看跌吞没 ,'[看跌吞没] 在顶部出现有下挫可能,在中间出现有可能是下跌中继；');
EXPLAIN( 出水芙蓉 ,'[出水芙蓉] 显示上攻势头；');

EXPLAIN( 穿头破脚1 and not(空方炮) ,'[穿头破脚] 经常出现于顶部附近,往往是见顶回落信号；');
EXPLAIN( 穿头破脚2 and not(多方炮) ,'[穿头破脚] 经常在底部或者上升途中出现,看涨回升信号；');
EXPLAIN( 低开大阳 and not(大阳烛) ,'[低开长阳] 往往是主力震仓收集筹码的迹象，行情有向上运行可能；');
EXPLAIN( 光头阳线 and not(曙光初现) and not(旭日东升) ,'[光头阳线] 多方积极上攻态势；');
EXPLAIN( 大阳烛 and not(光头阳线) and not(出水芙蓉) ,'[大 阳 线] 在上升行情中出现,意味着行情加速攀升；在下跌行情中出现,则意味着走势反弹；');
EXPLAIN( 长下影 and not(吊颈) and not(十字星) and not(长十字) and not(锤头) ,'[长 下 影] 持续下跌后出现,有可能止跌回升；若在升势末期出现,则须多加留意风险；');
EXPLAIN( 长上影 and not(射击之星) and not(十字星) and not(长十字) ,'[长 上 影] 表明上档压力较重,升势受阻;若出现在涨势初期或重要阻力价位处则有试盘的可能；');
EXPLAIN( 光脚长阴 and not(断头铡刀) and not(加速三阴) and not(看跌吞没) and not(倾盆大雨), '[光脚长阴] 看跌信号；');
EXPLAIN( 大阴烛 and not(光脚长阴) and not(加速三阴) and not(断头铡刀) and not(看跌吞没) and not(倾盆大雨) ,'[大 阴 线] 代表做空动力，注意开盘收盘价位，出现在低位上升途中则有洗盘的可能；');

{=============================================== 引用成交量判断顶底走势 ===============================================}
MV5 :=MA(vol,5);
MV10:=MA(vol,10);
MV20:=MA(VOL,20);

放量:=((VOL>REF(VOL,1) AND VOL>2*MV10) or (VOL>3*MV10 AND VOL>2*MV5) or (vol>1.5*ref(vol,1) AND VOL>1.6*MV5))
and ((换手率>2.0 and not(上升趋势)) or (换手率>3.0 and 上升趋势));
过分放量:=vol>2*ref(vol,1) and vol>1.6*MV5 and 换手率>3.0;

{ pay attention!!! }
放量123:=vol>1.5*ref(vol,1) and vol>1.8*MV5 and ref(vol,1)>1.5*ref(vol,2) {and EVERY (阳线,2)} and 换手率>2.0;
缩量:=vol<(max(MV10,MV5)*1.2) and vol<(ref(vol,1)*0.8);

{ pay attention!!! }
成交放大:=vol>min(MV10,MV5);
持续成交放大:=成交放大 and ref(成交放大,1) and ref(成交放大,2);
持续温和放量:=MV5>ref(MV5,5) and MV5>MV10 and hhv(vol,6)<2.4*MV5 and llv(vol,6)>0.3*MV20 {and EVERY (阳线,6) and EVERY (not(过分放量),6)}
and not(多头排列) and 持续成交放大 and MV5/capital<3 and 换手率<8;

HSL=(VOL/CAPITAL);
EXPLAIN(C>0,'───【资金量能分析】───'),COLORYELLOW;
{EXPLAINEX(1,'成交笔数：',QT,2,0),COLORGREEN;}
EXPLAINEX(HSL<10,'换 手 率 %：',HSL,2,0),COLORFFCC99;
EXPLAINEX(HSL>10 and HSL<18,'换 手 率 %：',HSL,2,0),COLOR0066CC;
EXPLAINEX(HSL>18,'换 手 率 %：',HSL,2,0),COLOR9966FF;

放量后缩量:=(ref(放量,1) or (ref(放量,2) and ref(vol,1)>0.8*ref(vol,2) and 换手率>3.0)) and vol<ref(vol,1)*0.6 and max(open,close)>MA1;
放量后缩量见顶:=((ref(放量,1) or (ref(放量,2) and ref(vol,1)>0.8*ref(vol,2) and 换手率>3.0)) and vol<ref(vol,1)*0.56 and max(open,close)>MA1
and (十字星 or 升势尽头 or 吊颈 or 身怀六甲1 or 乌云盖顶 or 长上影 OR 平顶)) and not(涨停板) and ref(阳线,1);
见顶K线:={(十字星 and high<>close) or} 升势尽头 or 吊颈 or 身怀六甲1 or 乌云盖顶 or 穿头破脚1 or 长上影;
逃顶K线:=(穿头破脚1 and ref(吊颈,1)) or 倾盆大雨;
放量见顶:=放量 and 见顶K线 and max(open,close)>MA1;

EXPLAIN( HSL>20 ,'成交活跃换手过高,注意走势变化');
EXPLAIN( 放量见顶 ,'放量明显,结合K 线形态注意震荡');
EXPLAIN( 放量123 and not(放量见顶) and 阳线 ,'加速放量,关注量能释放的持续性');
EXPLAIN( 放量123 and 大阴烛 ,'放量杀跌，适当注意风险');
EXPLAIN( 放量后缩量见顶 ,'成交量能持续性不好,结合K线形态注意短期震荡风险');

EXPLAIN((放量 and 出水芙蓉) ,'放量突破,运行节奏可能变化');
EXPLAIN( 持续温和放量 AND close<MA5 ,'持续温和放量');
EXPLAIN((MV10/CAPITAL)*100<0.5 and hhv(换手率,3)<1.00 AND not(持续成交放大) ,'持续成交低迷,注意近期有无放量迹象');

放量突破:=放量 and 出水芙蓉;

{============================================== 资金流向分析 ===============================================}
{ ddx="大单比率.大单比率" ; }
EXPLAIN(C>0,'----------------------------'),COLORYELLOW;
主力净买:= (BIGORDER(1,2)-BIGORDER(2,2))*vol;
大单比率:= 主力净买/CAPITAL ;
ddx:=大单比率;
大单泛绿天数:= COUNT( ddx<0,9 );
大单泛红天数:= count( ddx>0,10 );

聚散程度:=10*(ORDER(2)-ORDER(1))/CAPITAL;
筹码泛绿天数:= count( 聚散程度<0,10 );
筹码泛红天数:= count( 聚散程度>0,10 );

机构:= (BIGORDER(1,3)-BIGORDER(2,3))*vol/CAPITAL;
大户:= (BIGORDER(1,2)-BIGORDER(2,2)-BIGORDER(1,3)+BIGORDER(2,3))*vol/CAPITAL;
散户:= (BIGORDER(2,1)-BIGORDER(1,1))*vol/CAPITAL;

资金持续流入:= 大单泛红天数>6 and ddx> 0.10 and 筹码泛红天数>6 and 聚散程度> 0.10 and 散户<0 and LLV(ddx,8)>-0.20;
资金持续流出:= 大单泛绿天数>6 and ddx<-0.10 and 筹码泛绿天数>6 and 聚散程度<-0.07 and 散户>0 and HHV(ddx,8)< 0.20;

内盘成交:=ORDERNWP(1) ; 外盘成交:=ORDERNWP(2) ;
DKDL:= 100*(外盘成交-内盘成交)/vol ;

EXPLAINEX( ddx<=0.40 and ddx>=-0.40 ,'大单比率 %：',ddx, 2, 0);
EXPLAINEX( ddx<1 and ddx>0.40,'大单比率 %：',ddx, 2, 0),COLORYELLOW;
EXPLAINEX( ddx>=1,'大单比率 %：',ddx, 2, 0),COLOR9933FF;
EXPLAINEX( ddx>-1 and ddx<-0.40,'大单比率 %：',ddx, 2, 0),COLORYELLOW;
EXPLAINEX( ddx<=-1,'大单比率 %：',ddx, 2, 0),COLORgreen;
{
EXPLAINEX( 聚散程度<=-2,'筹码聚散 %：',聚散程度, 2, 0),COLORgreen;
}
EXPLAIN(ddx>0.30 and ddx<1 and 聚散程度>0.36 and 散户<0.20 , '有资金吸筹迹象，可进行跟踪 '),COLOR3333CC;
EXPLAIN(ddx>= 1 and ( DKDL> 30 or 聚散程度>1 ) and DKDL>0 , '有资金主动介入，可适当关注 '),COLOR3333CC;
EXPLAIN(ddx>= 1 and 聚散程度>0.80 and DKDL<-5 and 机构>0.20,'有大资金参与，筹码趋于集中 '),COLOR3333CC;

EXPLAIN(ddx< -0.40 and ddx>-0.60 and 聚散程度<-0.40 and 散户>0.2 and 大户<0, '筹码松动，主力的减仓意愿较强 '),COLORGREEN;
EXPLAIN(ddx<=-0.60 and 聚散程度<-0.70 and DKDL>=0 and 散户>0.20, '筹码松动，注意有资金正在减仓 '),COLORGREEN;
EXPLAIN(ddx<= -1 and 聚散程度<-1 and DKDL< 0 and 机构<-0.5, '卖压加大，警惕主力资金在出逃 '),COLORGREEN;

EXPLAIN( 资金持续流入 , '资金正在持续流入，筹码趋于集中 '),COLORRED;
EXPLAIN( 资金持续流出 , '资金正在持续流出，筹码趋于分散 '),COLORGREEN;

{=========================================== 机会风险综合评估 ===============================================}

下跳孤星:=max(open,close)<ref(close,1) and abs(close-open)/close<0.025;

抄底标识:=(空头排列 and 均线向下发散 AND (加速三阴 or ref(加速三阴,1) or 倒转锤头 or 身怀六甲2))
or (ref(空头排列,1) and ref(均线向下发散,1) AND (身怀六甲2 or 跌势尽头))
or (ref(空头排列,1) and ref(均线向下发散,2) AND (早晨之星))
or ((( (ref(加速三阴,1) or ref(空方炮,1)) and ref(空头排列,1) and 均线发散程度<0.94) or ref(均线向下发散,1)) and (身怀六甲2 or 曙光初现 {or 下跳孤星} ));
冲顶标识:=(冲顶三阳 and 均线向上发散 and (VOL/CAPITAL)*100>4.0) or (ref(均线向上发散,1) and (身怀六甲1 or 升势尽头))
or ( vol>1.2*ref(vol,1) and (长上影 or 见顶缺口) and 均线向上发散 and (换手率>5.00))
or ((乌云盖顶 or 倾盆大雨) and ref(均线向上发散,1) and (换手率>2.50))
or (放量后缩量见顶 and 均线向上发散)
or (放量后缩量 and ref(均线向上发散,1))
or (换手率>25 and 均线向上发散 );
追涨标识:=({(看涨吞没 and open<=MA1 and close>MA2 and not(均线向上发散)) or} 出水芙蓉)
or ((上升趋势形成 or 均线密集 or ref(均线密集,1)) and (多方炮 or 看涨吞没 or 穿头破脚2 ))
or ( 上升趋势形成 and 跳空缺口1 and 光头阳线)
or ( 0轴上金叉 and (多方炮 or 看涨吞没 or 穿头破脚2 or 跳空缺口1 or (光头阳线 and 大阳烛)));

aa:= (0轴上金叉 and (多方炮 or 看涨吞没 or 穿头破脚2 )) and CPX>0;

B点:= CPX=1 and ref(CPX,1)<0;
SB翻转:= CPX=1 and ref(CPX,1)<0 and ref(CPX,2)>0;

{------------------------------------------------------------------------------------------------------------------}
风险1:=身怀六甲1 or 升势尽头 or (吊颈 and not(涨停板)) or (长上影) ;
风险2:=(身怀六甲1 or 升势尽头 or 吊颈 or 穿头破脚1 or 看跌吞没) and 缩头 ;
风险3:=冲顶标识 and not(涨停板) ;
风险4:=放量后缩量见顶 or 放量见顶 or 逃顶K线 and CPX> 0 ;
风险5:=(断头铡刀 or 穿头破脚1 or 看跌吞没 or 倾盆大雨 or 光脚阴线 ) and CPX> 0 ;
风险6:=(断头铡刀 or 穿头破脚1 or 看跌吞没 or 倾盆大雨 or 光脚阴线 or 大阴烛 or 缩头) and CPX=-1 ;
风险 := 风险1 or 风险2 or 风险3 or 风险4 or 风险5 or 风险6;

机会1:=大阳烛 AND 下跌趋势 and 空头排列 and ddx>0.20 ;
机会2:=(跌势尽头 or (身怀六甲2 and 倒转锤头)) ;
机会3:=抄底标识 and not(跌停板) ;
机会4:=SB翻转 and ddx>0.10 ;
机会5:=追涨标识 and CPX>0 and HSL<12 and ddx>0.20;
机会 :=机会1 or 机会2 or 机会3 or 机会4 or 机会5;

{============================================【机会风险评估】==================================================}
EXPLAIN(C>0,' '),COLORRED;
EXPLAIN(C>0,'───【机会风险评估】───'),COLORRED;
{
EXPLAINEX( 1,'操盘线状态：',cpx , 2, 0) ;
EXPLAINEX( 1,'涨跌幅 %：',100*(close/open -1) , 2, 0) ;
}
{☆★○●●}
EXPLAIN( 风险1 and not(风险2),'短期走势有不确定性，以观望为主，建议关注走势变化。★'),colorFFCC66;
EXPLAIN( 风险2 and not(风险3),'走势有停滞迹象，可能出现短期顶部，建议提高警惕。★★'),colorFFAA00;
EXPLAIN( 风险3 and not(风险4),'走势加速上攻，短线超买比较明显，可能面临调整，建议密切注意。★★★'),colorFFAA00;
EXPLAIN( 风险4 and not(风险5),'可能震荡整理，建议控制仓位。★★★'),colorFFAA00;
EXPLAIN( 风险5 and not(风险6),'当前走势不佳，结合操盘线信息注意防范风险。★★★★'),color88CC66;
EXPLAIN( 风险6 and not(机会) ,'走势较为恶劣，注意控制风险。★★★★★'),colorFFAA00;

EXPLAIN( 机会1 and not(机会3),'下跌过程中反弹，持续性有待观察。●'),color6633CC;
EXPLAIN( 机会2 and not(机会3),'走势可能面临转折，建议积极关注。●●'),color6633CC;
EXPLAIN( 机会3, '近期走势较弱，走势加速探底，超跌比较严重，可能面临反弹，需注意走势变化。●●'),color6633CC;
EXPLAIN( 机会4 and not(机会5),'走势突变，关注短线机会。●●●'),color6633CC;
EXPLAIN( 机会5 and not(风险) ,'走势较为乐观，可考虑适量参与。●●●●'),color6633CC;
 

[url=http://www.goodgupiao.com/gupiaogongshi/18185.html][B]操盘手指标“实时解盘"[/B][/url]