常用主图(主图 指标)

好股网(www.goodgupiao.com)提示：您正在下载的是：常用主图(主图 指标)

MA5:MA(C,5),COLOR0000FF,NODRAW;
MA10:MA(C,10),COLOR00FFFF,NODRAW;
MA20:MA(C,20),COLORC050AB,NODRAW;
SJYY:=IF(PERIOD=5,1.95,IF(PERIOD=4,1.98,IF(PERIOD<=3,2,2.1)));
上轨:MA(C,20)+2.1*STD(C,20),COLORFFFBBB,DOTLINE,NODRAW;
下轨:MA(C,20)-SJYY*STD(C,20),COLORFFFBBB,DOTLINE,NODRAW;

速率M5:(MA5/REF(MA5,1)-1)*100,COLORFFFFFF,NODRAW;
速率M10:(MA10/REF(MA10,1)-1)*100,COLOR00FFFF,NODRAW;
速率M20:(MA20/REF(MA20,1)-1)*100,COLORFF00FF,NODRAW;
五H乖离:(H/MA(H,5)-1)*100,NODRAW;
获利:EMA(WINNER(C)*100,5),NODRAW;
M5速率向上:=速率M5>=REF(速率M5,1);
M10速率向上:=速率M10>=REF(速率M10,1);
M20速率向上:=速率M20>=REF(速率M20,1);
M5速率向下:=速率M5<REF(速率M5,1);
M10速率向下:=速率M10<REF(速率M10,1);
M20速率向下:=速率M20<REF(速率M20,1);
速率向上:=(M5速率向上+M10速率向上+M20速率向上)>=2;
速率向下:=(M5速率向下+M10速率向下+M20速率向下)>=2;
适合做T:=REF(速率向上,1) AND 速率向下 AND (H/MA(H,5)-1)*100>7 AND (H+MAX(C,O)/2)/2>REF((H+MAX(C,O)/2)/2,1);

长影星:=(H-L)/(ABS(C-O)+0.0001)>4 AND MAX(C,O)<REF(C,1) AND REF(MIN(C,O)<REF(MIN(C,O),1),1) AND MIN(C,O)<MA(C,5);
超微星:=(H-L)/(ABS(C-O)+0.0001)>8 AND MAX(C,O)/MIN(C,O)<1.001;
超跌星:=(H-L)/(ABS(C-O)+0.0001)>2.5 AND H>MAX(C,O) AND O<REF(C,1) AND REF(REF(C,1)/C>1.03,1) AND REF(MIN(C,O),1)>L*1.02 AND (C+O)/2<MA(C,5);
平底阳:=C>O AND L>=O*0.997 AND MAX(C,O)<REF(C,1) AND REF(C,1)<REF(C,2) AND MA(C,3)<REF(MA(C,3),1);
倒T星:=(H-L)/(ABS(C-O)+0.0001)>8 AND REF(C,1)>(H-L)/2 AND REF(C,1)<REF(C,2) AND MA(C,3)<REF(MA(C,3),1);
长T星:=(H-L)/(ABS(C-O)+0.0001)>8 AND REF(C,1)>MAX(C,O) AND MIN(C,O)/L*1.03 AND REF(C,1)<REF(C,2) AND MA(C,3)<REF(MA(C,3),1);
止跌K:=长影星 OR 超微星 OR 超跌星 OR 平底阳 OR 倒T星 OR 长T星;

下跳空:=MAX(C,O)<REF(L,1) AND REF(C,1)<REF(C,2) AND MA(C,3)<REF(MA(C,3),1);
上跳空:=MIN(C,O)>REF(MAX(C,O),1)*1.001;
阳吞阴:=REF(C,1)<REF(C,2)*0.95 AND C>REF(MAX(C,O),1) AND C>REF(C,1)*1.045 AND V>REF(V,1) AND MA(C,5)<REF(MA(C,5),1) AND HHV(H,5)/LLV(L,2)>1.15;
阴吞阳:=REF(C,1)>REF(C,2) AND REF(H,1)/REF(C,2)*1.05 AND C<REF(C,1)*0.95 AND ABS(C-O)>REF(ABS(C-O),1) AND O>REF(C,1) AND REF(KDJ.K>70,1);
反转:=(上跳空 AND REF(下跳空 AND 止跌K,1)) OR 阳吞阴;

STICKLINE(反转 AND C>=O,H,L,5,0),COLORA0A0A0;
STICKLINE(阴吞阳,H,L,5,0),COLOR125800;

STICKLINE(获利<48 AND C>=O,H,L,0,0),COLOR0005AA;
STICKLINE(获利<48 AND C>=O,C,O,3.2,1),COLOR0005AA;
STICKLINE(获利<48 AND C<O,H,L,0,0),COLOR666000;
STICKLINE(获利<48 AND C<O,C,O,3.2,0),COLOR666000;

STICKLINE(获利>=48 AND C>=O,H,L,0,0),COLOR881188;
STICKLINE(获利>=48 AND C>=O,C,O,3.2,0),COLOR881188;
STICKLINE(获利>=48 AND C<O,H,L,0,0),COLOREEE000;
STICKLINE(获利>=48 AND C<O,C,O,3.2,1),COLOREEE000;

STICKLINE(获利>=78 AND C>=O,H,L,0,0),COLOREE88EE;
STICKLINE(获利>=78 AND C>=O,C,O,3.2,0),COLOREE88EE;
STICKLINE(获利>=78 AND C<O,H,L,0,0),COLORC0C0C0;
STICKLINE(获利>=78 AND C<O,C,O,3.2,1),COLORC0C0C0;

STICKLINE(获利>=88 AND C>=O,H,L,0,0),COLOR0000FF;
STICKLINE(获利>=88 AND C>=O,C,O,3.2,0),COLOR0000FF;
STICKLINE(获利>=88 AND C<O,H,L,0,0),COLOR00A500;
STICKLINE(获利>=88 AND C<O,C,O,3.2,1),COLOR00A500;

STICKLINE(ROUND2((C/REF(C,1)-1)*10,2)>=0.93 AND C=H,C,O,1,0),COLOR00FFFF;
STICKLINE(ROUND2((C/REF(C,1)-1)*10,2)<=-0.93 AND L=C,C,O,1,0),COLOR00FF00;

STICKLINE(L>REF(H,1),L,REF(H,1),3.8,-1),COLORFF00FF;
STICKLINE(H<REF(L,1),H,REF(L,1),3.8,-1),COLOR00FF00;

ZT:=C/REF(C,1)>1.097;
K18:=SMA((C-LLV(L,18))/(HHV(H,18)-LLV(L,18))*100,3,1);
相对低位:=K18<25 OR RSI.RSI2<35 OR BIAS.BIAS1<-9 OR KDJ.K<30;
ZTLL:=ZT AND REF(相对低位,1);
STICKLINE(FILTER(ZTLL,3),C,O,3.3,0),COLOR00FFFF;

UP:=MA20+2*STD((H+L)/2,20);
LP:=MA20-2*STD((H+L)/2,20);

十日量能平台:=IF(HHV(V,10)=V AND ROUND2((C/REF(C,1)-1)*10,2)>=0.3,H,0);
STICKLINE(BARSLAST(十日量能平台),REF(H,BARSLAST(十日量能平台)),REF(H,BARSLAST(十日量能平台)),1,0),COLORFF1111,LINETHICK1;
STICKLINE(BARSLAST(十日量能平台),REF(L,BARSLAST(十日量能平台)),REF(L,BARSLAST(十日量能平台)),1,0),COLOR555555,LINETHICK1;

上轨,COLORFFFBBB,DOTLINE;
下轨,COLORFFFBBB,DOTLINE;
DTQS:=IF(MA5>=REF(MA5,1),1,0)+IF(MA10>=REF(MA10,1),1,0)+IF(MA20>=REF(MA20,1),1,0);
多头:=MA5>MA10 AND DTQS>0;
回抽:=MA5<MA10 AND MA10>MA20 AND DTQS>0;
强多头:=MA5>MA10 AND DTQS>=2;
最强多头:=MA5>MA10 AND MA10>MA20 AND DTQS=3;
IF(多头,下轨,DRAWNULL),COLORFFFFFF,CIRCLEDOT,LINETHICK2;
IF(回抽,下轨,DRAWNULL),COLOR00DDDD,CIRCLEDOT,LINETHICK2;
IF(强多头,下轨,DRAWNULL),COLOR0005DD,CIRCLEDOT,LINETHICK2;
IF(最强多头,下轨,DRAWNULL),COLORFF00FF,CIRCLEDOT,LINETHICK2;

MA20,COLORFF3333,LINETHICK1;
IF(MA20>=REF(MA20,1),MA20,DRAWNULL),COLORC050AB,LINETHICK2;
MA10,COLOR00FF00;
IF(MA10>=REF(MA10,1),MA10,DRAWNULL),COLOR00FFFF,LINETHICK2;
MA5,COLORFFFFFF;
IF((MA5/REF(MA5,1)-1)*100<-1,MA5,DRAWNULL),COLORFFF000,LINETHICK1;
IF((MA5/REF(MA5,1)-1)*100>2.5,MA5,DRAWNULL),COLORFF00FF,LINETHICK1;
IF((MA5/REF(MA5,1)-1)*100>5,MA5,DRAWNULL),COLOR0000FF,LINETHICK2;

底部缺口牛:=REF(C/HHV(H,60),1)<0.8 AND L>REF(H,1) AND REF(C/REF(C,5),1)<1.1;
DRAWICON(FILTER(底部缺口牛,3),REF(C,1)*0.98,29);

VAR1G:=(((CLOSE / MA(CLOSE,40)) * 100) < 78);
VAR2G:=(((CLOSE / MA(CLOSE,60)) * 100) < 74);
VAR3G:=(HIGH > (LOW * 1.051));
VAR4G:=(VAR3G AND (COUNT(VAR3G,5) > 1));
VARAA:=IF((VAR4G AND (VAR1G OR VAR2G)),2,0);
VARBB:=C/REF(C,25)<=1.1;
VARCC:=(SMA(MAX(C-REF(C,2),0),7,1)/SMA(ABS(C-REF(C,2)),7,1)*100)<15;
操盘线:=SMA((CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100,2,1);
VARV5:=SMA(操盘线,2,1);
操盘线抄底:=操盘线>REF(操盘线,1) AND REF(操盘线,1)<REF(操盘线,2) AND 操盘线<23;
赢利极品底:=VARAA AND VARBB AND VARCC AND 操盘线抄底;
DRAWTEXT(赢利极品底,L,'←极品底'),COLOR00FF00;

QSKX:=EMA(EMA(EMA((2*CLOSE+HIGH+LOW)/4,3),3),3);
QSKXSL:=(QSKX-REF(QSKX,1))/REF(QSKX,1)*100;
QSKXJC:=CROSS(QSKXSL,MA(QSKXSL,2)) OR (CROSS(QSKXSL,0) AND COUNT(QSKXSL>MA(QSKXSL,2),2)=2);
JXTTJ1:=(MIN(MA5,MA10)>MA20 AND C>=MA5) AND MA10>=REF(MA10,1) AND COUNT(MA20>=REF(MA20,1),4)=4 AND REF(L<MA10,1) AND (C>O OR C>=REF(C,1));
JXTTJ2:=MA5>MAX(MA10,MA20) AND (BETWEEN((MA10/MA20-1)*100,-8,8) OR MA10>MA20) AND MA5>=REF(MA5,1) AND COUNT(MA10>=REF(MA10,1),2)=2 AND COUNT(MA20>=REF(MA20,1),4)=4 AND REF(C<MA5 AND C>MA20,1) AND (C>O OR C>=REF(C,1));
JXTTTJ:=JXTTJ1 OR JXTTJ2 AND NOT(COUNT(MA20>=REF(MA20,1),25)=25);
QSKXTJ:=QSKXJC AND REF(BETWEEN(QSKXSL,-1.6,2),1) AND QSKXSL>0;
回调上攻:=JXTTTJ AND QSKXTJ;
DRAWICON(回调上攻,REF((L+O)/2,1),11);

跳高开:=L>(REF(H,1)+0.01);
跳低开:=H<(REF(L,1)-0.01);
跳低开T1:=HHV(H,BARSLAST(跳低开)+1);
跳低开T2:=REF(L,BARSLAST(跳低开)+1);
岛形反转:=REF(跳低开T1<跳低开T2,1) AND 跳高开 AND L>=REF(H,BARSLAST(跳低开));
DRAWTEXT(岛形反转,LOW-0.2,'←岛形'),COLORFFFFFF;

{短涨速过快风险}
MHGL:=(H/MA(H,5)-1)*100;
MCGL:=(C/MA(C,5)-1)*100;
减仓条件1:=MHGL>13 AND MHGL<MCGL AND MCGL/MHGL>1.2;
减仓条件2:=REF(MHGL>13,1) AND MHGL<REF(MHGL,1) AND H>REF(H,1);
减仓条件3:=REF(MHGL,1)>=14.9 AND REF(MCGL,1)>=14.9 AND ((REF(MHGL,1)>REF(MHGL,2) AND MHGL<REF(MHGL,1)) OR (REF(MCGL,1)>REF(MCGL,2) AND MCGL<REF(MCGL,1)));
短涨速风险:=(减仓条件1 OR 减仓条件2 OR 减仓条件3) AND 速率M10<REF(速率M10,1);
戒贪:=REF(WINNER(C)*100,1)>95 AND C>REF(C,1) AND WINNER(C)*100<REF(WINNER(C)*100,1)
AND (C-LLV(C,5))/LLV(C,5)*100>20 AND (H/MA(H,5)-1)*100>13;{信号当天和次日减仓}
RSV_9:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
KDJ_9:=SMA(RSV_9,3,1);
K值防顶:=(C/((HHV(C,10)+LLV(C,10))/2)-1)*100>=20 AND REF(KDJ_9>85,1) AND KDJ_9<REF(KDJ_9,1) AND H>REF(H,1);{K值背离注意风险}
DRAWTEXT(K值防顶 OR 短涨速风险 OR 戒贪,L*0.99,'←减仓'),COLORFFFFFF;

冲高就减:=O>(MA(C,20)+2.1*STD(C,20)) AND H/(MA(C,20)+2.1*STD(C,20))>1.04 AND NOT(H=C AND 0=C AND C/REF(C,1)>=1.095);
上轨超高:=H>(MA(C,13)+2.1*STD(C,13))*1.02;
DRAWICON(上轨超高 OR 冲高就减,H*1.03,15);

{明天高抛信号}
RSI24:=SMA(MAX(C-REF(C,1),0),24,1)/SMA(ABS(C-REF(C,1)),24,1)*100;
RSI12:=SMA(MAX(C-REF(C,1),0),12,1)/SMA(ABS(C-REF(C,1)),12,1)*100;
RSI6:=SMA(MAX(C-REF(C,1),0),6,1)/SMA(ABS(C-REF(C,1)),6,1)*100;
明天高抛:=(RSI6-RSI12)>2*(RSI12-RSI24) AND RSI6>75 AND C>REF(C,1)*1.05;
DRAWTEXT(FILTER(明天高抛,3),H*1.01,'←明减'),COLOR00FFFF;

DRAWTEXT(适合做T,H*1.01,'←减T'),COLORC055FF;

DRAWTEXT_FIX(ISLASTBAR,0,0,0,'风格:'),COLORFFFFFF;
DRAWTEXT_FIX(ISLASTBAR,0.03,0,0,FGBLOCK),COLOR00FF00;
DRAWTEXT_FIX(ISLASTBAR,0,0.06,0,'概念:'),COLORFFFFFF;
DRAWTEXT_FIX(ISLASTBAR,0.03,0.06,0,GNBLOCK),COLORFF00FF;
DRAWTEXT_FIX(ISLASTBAR,0,0.12,0,'行业:'),COLORFFFFFF;
DRAWTEXT_FIX(ISLASTBAR,0.03,0.12,0,HYBLOCK),COLOR00FFFF;
DRAWTEXT_FIX(ISLASTBAR,0,0.18,0,'地区:'),COLORFFFFFF;
DRAWTEXT_FIX(ISLASTBAR,0.03,0.18,0,DYBLOCK),COLORFFF000;
 

 

好股网(www.goodgupiao.com)提醒您：股市有风险，投资需谨慎。