S理论指标：股票短趋势副图源码 通达信 贴图

好股网(www.goodgupiao.com)提示：您正在下载的是：S理论指标：股票短趋势副图源码 通达信 贴图

本指标为股票短趋势，属于网络优秀指标，本人只是修改和明示出中枢三分类： 玫瑰红线为上涨的中枢上中下轨，深蓝线为下跌的中枢上中下轨，灰色线为震荡的中枢上中下轨。

原理：跟踪趋势划线，由于趋势型指标有一个劣势就是滞后，所以使用本指标时要注意滞后问题，如果学习本指标，建议使用沙盘演示，多了解划线的变化。

研究：研究本指标目的是了解趋势划线的变化，后来引入了自己的思路，把趋势分为三大区间：上涨区间，震荡区间和下跌区间，而三大区间各自形成一个中枢，中枢意义就是在区间中我们是否适合高抛低吸或追涨杀跌，最后，配合仓位管理后，明确每个区间的交易功能，通过这指标就可以一次解决技术和仓位的问题，因为划线本身就是技术，区间就是仓位管理。

运用： 上涨区间的中枢有三条玫瑰红线，这就是高抛低吸或追涨杀跌的位置，是否逢高减仓还是突破追高，就看个人操作风格，而黄色线属于仓位控制线；
下跌区间的中枢有三条深蓝线，这就是高抛低吸或追涨杀跌的位置，是否逢低加仓还是突破杀跌，就看个人操作风格，而黄色线属于仓位控制线；
震荡区间的中枢有五条灰色线，这就是行情的大中枢，亦是多空博弈的重要区间，是否高抛低吸或追涨杀跌，就看个人操作专业；
本指标最大劣势就是滞后，那么我们怎么办，我们可以引入一些波段式指标，提前预示行情拐点情况， 本人使用自己的中枢概念的指标，提前预警短线转向情况，而做好后面的操作计划。
本人操作仓位一般在于：20%-80%, 请按个人资金管理能力进行自我调整，风控第一。
以下有图解，仅供参考，毕竟不同人有着不同风格，前提必须做好风控工作。

适用： 任何市场品种和周期

引用一个期货朋友的话，就能说明仓位管理的重要性：
“理论上说， 做趋势跟踪策略的人，趋势挣的钱，基本上会在震荡里面亏个精光。 所以趋势跟踪也不像大家看起来那么容易。 真正做成功的，一定是仓位管理上面略胜一筹。也就是说，趋势的时候仓位大，挣了大钱， 然后震荡时仓位小，或者干脆去钓鱼度假去了。”

本贴仅供技术研究与学习参考，不作任何交易依据，盈亏自负！



DRAWKLINE(H,O,L,C);
UR:=250;{自行调节参数为长中短}
LR:=250;{自行调节参数为长中短}
TC1:=IF(H=HHV(H,1*UR),H,DRAWNULL);
TC2:=CONST(BARSLAST(TC1=H))+1;
UPPER:=CONST(IF(TC2=1,H,REF(H,TC2-1)));
BC1:=IF(L=LLV(L,1*LR),L,DRAWNULL);
BC2:=CONST(BARSLAST(BC1=L))+1;
LOWER:=CONST(IF(BC2=1,L,REF(L,BC2-1)));
LP:=CURRBARSCOUNT<=BC2 AND L=LOWER;{低点定位}
HP:=CURRBARSCOUNT<=TC2 AND H=UPPER;{高点定位}
STICKLINE(IF(BC2>TC2,HP,LP),LOWER,UPPER,0,0),COLOR628962;
STICKLINE(IF(BC2>TC2,LP,HP),LOWER,UPPER,0,0),COLOR628962;
NOD:=(IF(TC2>BC2,TC2,BC2)-IF(TC2>BC2,BC2,TC2));{用时}
LR1:=MA(C,NOD+1);
NP:IF(CURRBARSCOUNT<=MAX(BC2,TC2),CONST(IF(MIN(TC2,BC2)=1,LR1,REF(LR1,MIN(TC2,BC2)-1))),DRAWNULL),POINTDOT,COLOR93BDA8;{近点}
LR2:=SLOPE(C,NOD+1);
LR3:=CONST(IF(MIN(TC2,BC2)=1,LR2,REF(LR2,MIN(TC2,BC2)-1)));
FP:=NP-LR3*(NOD),POINTDOT,COLOR93BDA8;{远点}
EQU:(NP+FP)/2,POINTDOT,COLOR93BDA8;{中点}

A:(NP+EQU)/2,COLORGRAY;
B:(NP+A)/2,COLORGRAY;
D:(EQU+A)/2,COLORGRAY;

AD:=ABS(NP-FP);{高差};
DBL:=BARSLAST(BC1!=DRAWNULL)+1;
DBH:=BARSLAST(TC1!=DRAWNULL)+1;
BSP:=IF(BC2>TC2,DBL,DBH)-1;
LRL:=IF(NP>FP,FP+AD/NOD*BSP,FP-AD/NOD*BSP);
AT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND H>LRL,H,LRL);
AT2:=HHV(AT1-LRL,MAX(BC2,TC2));
AT3:=CONST(BARSLAST(AT1-LRL=AT2));
AT4:=CONST(IF(AT3=0,H,REF(H,AT3)));
AT5:=CONST(IF(AT3=0,AT1-LRL,REF(AT1-LRL,AT3)));
ATL:=LRL+AT5;
UT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND L<LRL,L,LRL);
UT2:=HHV(LRL-UT1,MAX(BC2,TC2));
UT3:=CONST(BARSLAST(LRL-UT1=UT2));
UT4:=CONST(IF(UT3=0,H,REF(H,UT3)));
UT5:=CONST(IF(UT3=0,LRL-UT1,REF(LRL-UT1,UT3)));
UTL:=LRL-UT5;
RH:=IF(CURRBARSCOUNT>=MAX(BC2,TC2)-5,ATL,CONST(REF(ATL,MIN(BC2,TC2)-5)));{限制高}
RL:=IF(CURRBARSCOUNT>=MAX(BC2,TC2)+5,UTL,CONST(REF(UTL,MIN(BC2,TC2)+5)));{限制低}

上:IF(NP>FP,IF(ATL<=RH,ATL,DRAWNULL),IF(ATL>=RL,ATL,DRAWNULL)),COLORLIRED;
下:IF(NP>FP,IF(UTL<=RH,UTL,DRAWNULL),IF(UTL>=RL,UTL,DRAWNULL)),COLORLIBLUE;
中轨:IF(C>0,(上+下)/2,DRAWNULL),COLORYELLOW;

上轨:=IF(上>REF(上,1),上,DRAWNULL),COLORLIRED;
下轨:=IF(下<REF(下,1),下,DRAWNULL),COLORGREEN;

(上轨+中轨)/2,COLORLIRED,DOTLINE;
(下轨+中轨)/2,COLORGREEN,DOTLINE;
中轨-(上轨-(上轨+中轨)/2),COLORLIRED,DOTLINE;
中轨+((下轨+中轨)/2-下轨),COLORGREEN,DOTLINE;

{以下是股票之友自创思路和划线}
辅助下:=IF(NP>FP,IF(UTL<=RH,UTL,DRAWNULL),IF(UTL<=RL,UTL,DRAWNULL)),COLORLIBLUE;
辅助下轨:=IF(辅助下<REF(辅助下,1),辅助下,DRAWNULL),COLORGREEN;
辅助中轨:=IF(C>0,(上+辅助下)/2,DRAWNULL),COLORYELLOW;
HHV(辅助中轨,0),COLORYELLOW;

IF(上>REF(上,1) AND HHV(上,0)=REF(HHV(上,0),1),HHV(上,0),DRAWNULL),COLORLIMAGENTA,DOTLINE,LINETHICK3;
IF(上>REF(上,1) AND HHV(上,0)=REF(HHV(上,0),1),HHV((上轨+中轨)/2,0),DRAWNULL),COLORLIMAGENTA,DOTLINE,LINETHICK3;
IF(上>REF(上,1) AND HHV(上,0)=REF(HHV(上,0),1),HHV(中轨-(上轨-(上轨+中轨)/2),0),DRAWNULL),COLORLIMAGENTA,DOTLINE,LINETHICK3;
IF(辅助下<REF(辅助下,1) AND HHV(辅助下,0)=REF(HHV(辅助下,0),1),HHV(辅助下,0),DRAWNULL),COLORBLUE,DOTLINE,LINETHICK3;
IF(辅助下<REF(辅助下,1) AND HHV(辅助下,0)=REF(HHV(辅助下,0),1),HHV((辅助下轨+辅助中轨)/2,0),DRAWNULL),COLORBLUE,DOTLINE,LINETHICK3;
IF(辅助下<REF(辅助下,1) AND HHV(辅助下,0)=REF(HHV(辅助下,0),1),HHV((辅助中轨+((辅助下轨+辅助中轨)/2-辅助下轨)),0),DRAWNULL),COLORBLUE,DOTLINE,LINETHICK3;

IF(上>REF(上,1),上,DRAWNULL),COLORLIRED;
IF(下<REF(下,1),下,DRAWNULL),COLORGREEN;
(上轨+中轨)/2,COLORLIRED,DOTLINE;
(下轨+中轨)/2,COLORGREEN,DOTLINE;
中轨-(上轨-(上轨+中轨)/2),COLORLIRED,DOTLINE;
中轨+((下轨+中轨)/2-下轨),COLORGREEN,DOTLINE;

好股网(www.goodgupiao.com)提醒您：股市有风险，投资需谨慎。